import? 'MuzikaGromche.just.user'

build: build-debug build-release

build-release:
    dotnet build --configuration Release

build-debug:
    dotnet build --configuration Debug

clean:
    rm -rf    dist    MuzikaGromche/bin    MuzikaGromche/obj

plugin_dir := "$HOME/.config/r2modmanPlus-local/LethalCompany/profiles" / imperium_profile / "BepInEx/plugins/Oflor-MuzikaGromche/"

install-imperium:
    rm    -rf    "{{ plugin_dir }}"
    mkdir    "{{ plugin_dir }}"
    unzip    -q    dist/MuzikaGromche-Debug.zip    -d    "{{ plugin_dir }}"

run-imperium:
    DRI_PRIME=1 steam -applaunch 1966720 --doorstop-enable true --doorstop-target "Z:$HOME/.config/r2modmanPlus-local/LethalCompany/profiles/{{ imperium_profile }}/BepInEx/core/BepInEx.Preloader.dll" --r2profile "{{ imperium_profile }}"

bump version_number:
    [[ "v{{ version_number }}" =~ ^v[0-9]+\.[0-9]+\.[0-9]+$ ]] || (echo "Invalid version format" && exit 1)
    jq --indent 4 --arg v "{{ version_number }}" '.version_number = $v' < manifest.json > manifest.json.copy
    mv manifest.json.copy manifest.json
    sed -i 's/<Version>.*<\/Version>/<Version>{{ version_number }}<\/Version>/' MuzikaGromche/MuzikaGromche.csproj